Sådan bruges Caps Lock som en ændringsnøgle på Windows

Caps Lock-tasten optager prime keyboard ejendom, og den trækker ikke sin vægt. Dette nemme AutoHotkey-script vil forvandle Caps Lock til en modifikationstast, så du kan bruge den til tilpassede genveje.

Indholdsfortegnelse

Det grundlæggende

Dette script giver dig mulighed for at trykke på Caps Lock+G for hurtigt at Google tekst fra hvor som helst i Windows eller trykke på Caps Lock+D for at slå ordbogsdefinitionen op for et ord. Disse genveje kan selvfølgelig tilpasses.

Det bedste af det hele er, at dette smarte script stadig lader dig bruge Caps Lock normalt. Du kan slå Caps Lock til og fra ved hurtigt at trykke to gange på den. Hvis du ikke gør det, fungerer Caps Lock som en modifikationstast til genveje.

AutoHotkey 101

AutoHotkey er et gratis Windows-program, der sidder i baggrunden og kører scripts. Du kan selv skrive disse scripts eller downloade dem. Scripts venter generelt på et tastetryk og udfører en handling. På denne måde er AutoHotkey en hurtig måde at omforme nøgler i Windows eller tildele forskellige handlinger til nøgler.

For eksempel har vi vist, hvordan du kan bruge AutoHotkey til at deaktivere Windows-tasten, hvilket forhindrer den i at åbne Start-menuen og tage dig ud af fuldskærms-pc-spil. Ingen grund til at lirke tastaturet af tastaturet.

Sådan administreres grafikydeevne pr. app på Windows 10

Installer AutoHotkey og få scriptet

Download AutoHotkey og installer det for at begynde. Download derefter CapsLock Modifier-scriptet.

Udpak AHK-scriptfilen fra ZIP-arkivfilen og placer den i en hvilken som helst mappe på din computer. For at køre det med AutoHotkey skal du højreklikke på scriptet og vælge “Kør script.”

Scriptet kører nu i baggrunden. For at slå Caps Lock til og fra skal du hurtigt dobbelttrykke på Caps Lock-tasten.

Hvis du ikke dobbelttrykker, fungerer Caps Lock blot som en ændringstast. Med funktionerne indbygget i scriptet kan du bruge følgende genveje hvor som helst i Windows:

Tryk på Caps Lock + d for at finde ordbogsdefinitionen af et valgt ord.
Tryk på Caps Lock + g for at søge på Google efter den valgte tekst hvor som helst i Windows.
Tryk på Caps Lock + t for at finde det valgte ord i en synonymordbog.
Tryk på Caps Lock + w for at søge efter den valgte tekst på Wikipedia.

Vil du have flere genveje? Du kan oprette din egen med lidt viden om AutoHotkey-scripts.

For at styre AutoHotkey skal du kigge efter AutoHotkey-ikonet i dit meddelelsesområde – det har en grøn baggrund med et hvidt H på. For at stoppe med at køre scriptet skal du bare højreklikke på AutoHotkey-ikonet og vælge “Afslut”.

Hvordan virker det?

Hvis du gerne vil se, hvad scriptet gør, skal du højreklikke på det og vælge “Rediger script” i stedet. Dette åbner scriptet i Notesblok, og du kan undersøge dets kode. Scriptet er ret kort og let at forstå. Vi anbefaler ikke at downloade og køre mærkelige scripts uden at se på dem og forstå dem først.

Deaktiver hurtig opstart i Windows 10 for en ordentlig nedlukning

Dette script blev sendt til os af Dave Kellog. Her er den magiske del af scriptet, der får Caps Lock til at fungere som en modifikationstast, hvis den trykkes to gange:

CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return

Denne bit venter på at se, om der trykkes på Caps Lock to gange og slår Caps Lock til eller fra. Ellers fanger scriptet Caps Lock og bruger det til modifikatorgenveje.

Resten af scriptet indeholder genvejshandlingerne og en nyttig udklipsholderfunktion, der gemmer indholdet af dit udklipsholder og gendanner dem. Den del er ret nødvendig, da modifikationsfunktionerne bruger udklipsholderen til at foretage handlinger på den valgte tekst.

Vil du se hele scriptet uden at downloade det? Her er det:

#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE       ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


;================================================================================================
;  CapsLock processing.  Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
    KeyWait, CapsLock                                                   ; Wait forever until Capslock is released.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Is a double tap on CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Toggle the state of CapsLock LED
        }
return



;================================================================================================
; Hot keys with CapsLock modifier.  See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.    
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Launch with contents of clipboard
    ClipboardRestore()
Return

; GOOGLE the selected text.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do THESAURUS of selected word
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do WIKIPEDIA of selected word
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Launch with contents of clipboard
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Save existing clipboard.
    Clipboard:= ""
    Send, ^c                                            ;Copy selected test to clipboard
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, No Text Selected!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

Vi har set AutoHotkey-scripts, der forvandler Caps Lock til en modifikationstast før, men aldrig en, der holder Caps Lock rundt som et skifte, hvis du dobbelttrykker på den. Det er meget smart. Tak igen til Dave Kellog for at sende den til os.

Sådan får du Windows til at ringe i timen